!===========================================================================
! **** New verbs ****

[KnuffelSub;
  "That is not something you would like to hug.";
  
];

[SpreekSub;
  "You wouldn't know what to say.";
];


[ KnockSub;
  "It would be rather useless to knock on that.";
];


[ PlaySub;
  "This is not the time for play.";
];

[ HuilSub;
  if(location == bos_2 && wolvin.status < 5) {<<spreek wolvin>>;};
  if(location == bos_2 && wolvin.status > 4 && wolvin.status < 7 && parent(jongewolf) == bos_2) {<<spreek jongewolf>>;};
  "You cannot cry on command.";
];

[ GromSub;
  if(location == bos_2 && wolvin.status < 5) {<<spreek wolvin>>;};
  if(location == bos_2 && wolvin.status == 99) {<<spreek jongewolf>>;};
  if(location == bos_2 && wolvin.status > 4 && wolvin.status < 7 && parent(jongewolf) == bos_2) {<<spreek jongewolf>>;};
  "You growl a bit, at the world in general.";
];

[DoofSub;
  "That is not something you can extinguish.";
 ];
 
[CrossSub;
  "It makes no sense to cross that.";
 ];
 
[InviteSub;
  "That only works with statues.";
 ];
 
[SitSub;
  "You don't feel like sitting, at the moment.";
];

[KreukSub;
  "Crumpling that is perhaps not the best option.";
];

[VloekSub;
  "You curse whole-heartedly.";
];

[VervloekSub;
  "You curse whole-heartedly.";
];

[AttackWithSub;
  if(verhaaltracker < 7) <<Attack noun>>;
  if(noun == player && second == final_scherf) {
    DoodMijMetScherf();
    return true;
   }
  if(noun == maartje && second == final_scherf && maartje.state == 1)
    { DoodMaartje(5); return true;}
  if(noun == maartje && second == final_kussen && maartje.state == 1)
    { DoodMaartje(4); return true;}
  <<Attack noun>>;
];

[FuckSub;
  "You don't feel any inclination to do that.";
];

[SuicideSub;
  <<Attack player>>;
];


!===================================================
!Extended grammar


Verb meta 'help' 'hulp' 'hint' 'copyright' 'copyleft' 'about' 'menu' 'info' * -> Menu;

Extend 'climb' * 'in'/'through' noun -> Climb;

Extend 'jump' * 'through' noun -> Climb
               * 'in'/'into' noun -> Enter
               * 'out' 'of' noun -> Climb;

Verb 'caress' 'stroke' 'pet' * noun -> Touch;


Verb 'leaf' 'thumb'
 * 'through' noun -> Examine;
  
 
Extend 'look'
 * 'out' 'of' noun -> Examine;
 
Extend only 'hug' * noun -> Knuffel;

Verb 'shred' 'tear' 'rend' 'rip'
 * noun -> Attack
 * 'apart' noun -> Attack
 * noun 'apart' -> Attack
 * 'up' noun -> Attack;

Extend 'kiss'
 * noun -> Kiss;
 
Extend only 'speak' first
 * 'to'/'with' creature -> Spreek;
 
Verb 'talk'
 * 'to'/'with' creature -> Spreek;
 
Verb 'knock'
   * noun -> Knock
   * 'on' noun -> Knock;
   
Extend 'attack'
   * noun 'with' held -> AttackWith;

Verb 'play'
   * 'with' noun -> Play
   * noun -> Play;
  
Verb 'cry' 'howl'
   * -> Huil
   * 'at'/'to'/'against' noun -> Grom;
   
Verb 'growl' 'grumble'
   * -> Grom
   * 'at'/'to'/'against' noun -> Grom;
   
Verb 'extinguish' 'smother' * noun -> Doof;

Extend 'put'
   * 'out' noun -> Doof;

Verb 'free' 'untie' 'loose' 'liberate'
      * noun -> Take;

Extend only 'cross'
      * noun -> Cross;

Extend only 'sit'
      * -> Sit;

Extend only 'set'
      * noun 'aflame'/'ablaze' -> Burn;

Verb 'invite'
      * noun -> Invite;

Verb 'crumple' 'crease' 'wrinkle' 'rumple'
      * noun -> Kreuk;
      
Verb 'curse'
      * -> Vloek
      * topic -> Vervloek;

Extend 'cut' * creature 'with' held -> AttackWith;

Verb 'snijd' * creature 'met' held -> AttackWith;

Verb 'rape' 'deflower'
     * creature -> Fuck
     * 'with' creature -> Fuck;

Extend only 'fuck'
     * creature -> Fuck
     * 'with' creature -> Fuck;

Extend only 'screw'
     * creature -> Fuck
     * 'with' creature -> Fuck;

Verb 'commit'
     * 'suicide' -> Suicide;
     
Verb 'suicide'
     * -> Suicide;